set term pngcairo size 448,330

set xrange  [-2 : 23]
set yrange  [0 : 51.75]
set y2range [0 : 94]
unset y2tics
set grid y

# Axes
set style line 11 lc rgb '#808080' lt 1
set border 3 back ls 11
set tics nomirror out scale 0.75
unset arrow 
set arrow from graph 0,1 to graph 0,1.05 size screen 0.025,15,60 filled ls 11

# Grid
set style line 12 lc rgb '#808080' lt 0 lw 1
set grid back ls 12

set title font "Liberation Sans, 10"
set key inside box lt -1 lc rgb '#a0a0a0' width -4.5 height .9 samplen 3 spacing .75 font "Liberation Sans, 10"
set ylabel 'Execution time (seconds)' offset 2,0 font "Liberation Sans, 10" textcolor rgb '#606060'
set xlabel ' ' offset 0,.5
set xtics offset 0,.25 font "Liberation Sans, 8"
set ytics offset .5,0 font "Liberation Sans, 8"

set style fill solid .5 border
set boxwidth 1.0
set title offset 0,-.5

set title "Cortex-A9, 48kHz stereo @ 96kbps VBR"
set xtics in ("encode\ncomplexity 9" 2.5, "encode\ncomplexity 0" 10.5, "decode" 18.5)

set output "omap48.png"
plot "omap10.m" title 'libopus 1.0.3' with boxes lc rgb '#c00000',\
  "omap10.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle, \
  "omap11.m" title 'libopus 1.1' with boxes lc rgb '#0060ad' ,\
  "omap11.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle


set title "Cortex-A9, wideband mono @ 16kbps VBR"
set xrange  [98 : 123]

set xtics in ("encode\ncomplexity 9" 102.5, "encode\ncomplexity 0" 110.5, "decode" 118.5)


set output "omapLP.png"
plot "omap10.m" title 'libopus 1.0.3' with boxes lc rgb '#c00000',\
  "omap10.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle, \
  "omap11.m" title 'libopus 1.1' with boxes lc rgb '#0060ad' ,\
  "omap11.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle


set title "i7-3520M @ 2.9GHz, wideband mono @ 16kbps VBR"
set xrange  [98 : 123]
set yrange  [0 : 28.75]

set xtics in ("encode\ncomplexity 9" 102.5, "encode\ncomplexity 0" 110.5, "decode" 118.5)

set output "coreLP.png"
plot "core10.m" title 'libopus 1.0.3' with boxes lc rgb '#c00000',\
  "core10.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle, \
  "core11.m" title 'libopus 1.1' with boxes lc rgb '#0060ad' ,\
  "core11.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle


set xrange  [-1 : 24]
set title "i7-3520M @ 2.9GHz, 48kHz stereo @ 96kbps VBR"
  set xtics in ("encode\ncomplexity 9" 1, "encode\ncomplexity 9/5*" 6.5, "encode\ncomplexity 0" 13.5, "decode" 20.5)

set output "core48.png"
plot "core10.m" title 'libopus 1.0.3' with boxes lc rgb '#c00000',\
  "core10.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle, \
  "core11.m" title 'libopus 1.1' with boxes lc rgb '#0060ad' ,\
  "core11.m" using 1:2:3 with labels font "Liberation Sans, 8" center offset 0,1.2 notitle


